# Maintainer: Joop Kiefte <ikojba@gmail.com>
#
# Builds The Puzzle Pits from the latest commit on GitHub:
#   cd packaging/arch && makepkg -si
pkgname=puzzle-pits-git
_pkgname=puzzle-pits
pkgver=r0
pkgrel=1
pkgdesc="The Puzzle Pits, Abe Pralle's 1995 DOS puzzle game, on SDL2"
arch=('x86_64' 'aarch64')
url="https://github.com/LaPingvino/The-Puzzle-Pits"
license=('Apache-2.0')
depends=('sdl2')
makedepends=('zig' 'git')
provides=('puzzle-pits')
conflicts=('puzzle-pits')
options=('!lto')
source=("$_pkgname-src::git+https://github.com/LaPingvino/The-Puzzle-Pits.git")
sha256sums=('SKIP')

pkgver() {
  cd "$srcdir/$_pkgname-src"
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

build() {
  cd "$srcdir/$_pkgname-src"
  ZIG_GLOBAL_CACHE_DIR="$srcdir/zig-cache" zig build -Doptimize=ReleaseSafe
}

package() {
  cd "$srcdir/$_pkgname-src"
  install -Dm755 zig-out/bin/puzzle-pits "$pkgdir/usr/bin/puzzle-pits"
  # the game finds its data in ../share/puzzle-pits from /usr/bin
  install -dm755 "$pkgdir/usr/share/puzzle-pits"
  cp -r PITS95/. "$pkgdir/usr/share/puzzle-pits/"
  install -Dm644 packaging/linux/puzzle-pits.desktop "$pkgdir/usr/share/applications/puzzle-pits.desktop"
  install -Dm644 packaging/linux/puzzle-pits.png "$pkgdir/usr/share/icons/hicolor/256x256/apps/puzzle-pits.png"
  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
  install -Dm644 README.md "$pkgdir/usr/share/doc/puzzle-pits/README.md"
}
