cmake_minimum_required(VERSION 3.20)

if (APPLE)
    set(CMAKE_OSX_DEPLOYMENT_TARGET "11.0" CACHE STRING "Minimum OS X deployment version")
endif()

project(BanjoRecompiled LANGUAGES C CXX)
set(CMAKE_C_STANDARD 17)
set(CMAKE_CXX_STANDARD 20)
set(CMAKE_CXX_STANDARD_REQUIRED ON)
set(CMAKE_CXX_EXTENSIONS OFF)
# set(CMAKE_CXX_VISIBILITY_PRESET hidden)
set(CMAKE_EXPORT_COMPILE_COMMANDS ON)

if (CMAKE_CXX_COMPILER_ID STREQUAL "Clang" AND CMAKE_CXX_SIMULATE_ID STREQUAL "MSVC")
    set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wno-everything /W4")
endif()

# Opt out of constexpr mutex constructor on windows to prevent vcredist issues
if (WIN32)
    set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -D_DISABLE_CONSTEXPR_MUTEX_CONSTRUCTOR")
endif()

if (APPLE)
    enable_language(OBJC OBJCXX)
endif()

if (CMAKE_SYSTEM_NAME MATCHES "Linux")
    option(RECOMP_FLATPAK "Configure the build for Flatpak compatibility." OFF)
endif()

# Avoid warning about DOWNLOAD_EXTRACT_TIMESTAMP in CMake 3.24:
if (CMAKE_VERSION VERSION_GREATER_EQUAL "3.24.0")
    cmake_policy(SET CMP0135 NEW)
endif()

set (CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR})
set (CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR})

if (WIN32)
    set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${CMAKE_SOURCE_DIR}/lib/")
endif()

set(RT64_STATIC TRUE)
set(RT64_SDL_WINDOW_VULKAN TRUE)
add_compile_definitions(HLSL_CPU)

if (CMAKE_SYSTEM_NAME MATCHES "Android")
    option(BANJO_ANDROID_SHELL_ONLY "Compatibility flag for the Android SDL lifecycle probe; the legacy text-view shell target is retired." OFF)
    option(BANJO_ANDROID_RENDERER_STUB "Use a no-op renderer context for Android probe builds." OFF)
    option(BANJO_ANDROID_SDL_LIFECYCLE_PROBE "Build an SDLActivity-driven Android lifecycle probe instead of the full runtime." OFF)
    option(BANJO_ANDROID_RUNTIME_APK "Build the real Android runtime as SDLActivity libmain.so." ON)
    option(BANJO_ANDROID_DEV_FULL_APK "Enable dev-only behavior for local Android APKs with bundled ROM assets." OFF)
    option(BANJO_ANDROID_VULKAN_SMOKE_PROBE "Compile the Android Vulkan smoke probe diagnostic into full Android builds." OFF)
    option(BANJO_ANDROID_CUSTOM_VULKAN_DRIVER "Enable Android custom Vulkan driver support through AdrenoTools." ON)
else()
    option(BANJO_ANDROID_SHELL_ONLY "Compatibility flag for the Android SDL lifecycle probe; the legacy text-view shell target is retired." OFF)
    option(BANJO_ANDROID_RENDERER_STUB "Use a no-op renderer context for Android probe builds." OFF)
    option(BANJO_ANDROID_SDL_LIFECYCLE_PROBE "Build an SDLActivity-driven Android lifecycle probe instead of the full runtime." OFF)
    option(BANJO_ANDROID_RUNTIME_APK "Build the real Android runtime as SDLActivity libmain.so." OFF)
    option(BANJO_ANDROID_DEV_FULL_APK "Enable dev-only behavior for local Android APKs with bundled ROM assets." OFF)
    option(BANJO_ANDROID_VULKAN_SMOKE_PROBE "Compile the Android Vulkan smoke probe diagnostic into full Android builds." OFF)
    option(BANJO_ANDROID_CUSTOM_VULKAN_DRIVER "Enable Android custom Vulkan driver support through AdrenoTools." OFF)
endif()

if (BANJO_ANDROID_CUSTOM_VULKAN_DRIVER)
    if (NOT CMAKE_SYSTEM_NAME MATCHES "Android")
        message(FATAL_ERROR "BANJO_ANDROID_CUSTOM_VULKAN_DRIVER is only supported for Android builds.")
    endif()

    set(BANJO_ADRENOTOOLS_DIR "${CMAKE_SOURCE_DIR}/lib/adrenotools" CACHE PATH "Path to libadrenotools checkout.")
    if (NOT EXISTS "${BANJO_ADRENOTOOLS_DIR}/CMakeLists.txt" OR
        NOT EXISTS "${BANJO_ADRENOTOOLS_DIR}/include/adrenotools/driver.h" OR
        NOT EXISTS "${BANJO_ADRENOTOOLS_DIR}/lib/linkernsbypass/CMakeLists.txt")
        message(FATAL_ERROR "BANJO_ANDROID_CUSTOM_VULKAN_DRIVER=ON requires libadrenotools with its nested liblinkernsbypass submodule at ${BANJO_ADRENOTOOLS_DIR}. Run: git submodule update --init --recursive lib/adrenotools")
    endif()
endif()

if (BANJO_ANDROID_SHELL_ONLY)
    if (NOT CMAKE_SYSTEM_NAME MATCHES "Android")
        message(FATAL_ERROR "BANJO_ANDROID_SHELL_ONLY is only supported for Android builds.")
    endif()

    if (NOT BANJO_ANDROID_SDL_LIFECYCLE_PROBE)
        message(FATAL_ERROR "BANJO_ANDROID_SHELL_ONLY now only supports the SDL lifecycle probe. The legacy MainActivity/BanjoAndroidShell text-view shell was retired; use -DBANJO_ANDROID_SDL_LIFECYCLE_PROBE=ON or build the runtime APK.")
    endif()

    find_package(SDL2 REQUIRED)

    add_library(main SHARED
        ${CMAKE_SOURCE_DIR}/src/android/sdl_lifecycle_probe.cpp
    )
    target_include_directories(main PRIVATE ${SDL2_INCLUDE_DIRS})
    target_link_libraries(main PRIVATE SDL2::SDL2 android log)

    if (BANJO_ANDROID_VULKAN_SMOKE_PROBE)
        target_sources(main PRIVATE
            ${CMAKE_SOURCE_DIR}/src/android/vulkan_smoke_probe.cpp
            ${CMAKE_SOURCE_DIR}/lib/rt64/src/contrib/plume/contrib/volk/volk.c
        )
        target_compile_definitions(main PRIVATE
            BANJO_ANDROID_VULKAN_SMOKE_PROBE=1
            BANJO_ANDROID_VULKAN_SMOKE_PROBE_STANDALONE=1
        )
        target_include_directories(main PRIVATE
            ${CMAKE_SOURCE_DIR}/src/android
            ${CMAKE_SOURCE_DIR}/lib/rt64/src/contrib
            ${CMAKE_SOURCE_DIR}/lib/rt64/src/contrib/plume/contrib/volk
            ${CMAKE_SOURCE_DIR}/lib/rt64/src/contrib/plume/contrib/Vulkan-Headers/include
        )
        if (BANJO_ANDROID_CUSTOM_VULKAN_DRIVER)
            add_subdirectory(${BANJO_ADRENOTOOLS_DIR} ${CMAKE_BINARY_DIR}/adrenotools)
            target_sources(main PRIVATE ${CMAKE_SOURCE_DIR}/src/android/custom_driver_manager.cpp)
            target_compile_definitions(main PRIVATE BANJO_ANDROID_CUSTOM_DRIVER_MANAGER=1 BANJO_ANDROID_CUSTOM_VULKAN_DRIVER=1)
            target_link_libraries(main PRIVATE adrenotools)
        endif()
    endif()

    return()
endif()

if (BANJO_ANDROID_RENDERER_STUB)
    add_compile_definitions(BANJO_ANDROID_RENDERER_STUB=1)
endif()

if (RECOMP_FLATPAK)
    add_compile_definitions(RECOMP_FLATPAK)
endif()

add_subdirectory(${CMAKE_SOURCE_DIR}/lib/rt64 ${CMAKE_BINARY_DIR}/rt64)

set(BUILD_SHARED_LIBS OFF)

if (BANJO_ANDROID_CUSTOM_VULKAN_DRIVER)
    add_subdirectory(${BANJO_ADRENOTOOLS_DIR} ${CMAKE_BINARY_DIR}/adrenotools)
endif()

add_subdirectory(${CMAKE_SOURCE_DIR}/lib/N64ModernRuntime)

target_include_directories(rt64 PRIVATE ${CMAKE_BINARY_DIR}/rt64/src)

# RecompiledFuncs - Library containing the primary recompiler output
add_library(RecompiledFuncs STATIC)

target_compile_options(RecompiledFuncs PRIVATE
    # -Wno-unused-but-set-variable
    -fno-strict-aliasing
    -Wno-unused-variable
    -Wno-implicit-function-declaration
)

target_include_directories(RecompiledFuncs PRIVATE
    ${CMAKE_SOURCE_DIR}/include
    ${CMAKE_SOURCE_DIR}/lib/N64ModernRuntime/ultramodern/include
    ${CMAKE_SOURCE_DIR}/lib/N64ModernRuntime/librecomp/include
    ${CMAKE_SOURCE_DIR}/lib/N64ModernRuntime/N64Recomp/include
)

file(GLOB FUNC_C_SOURCES ${CMAKE_SOURCE_DIR}/RecompiledFuncs/*.c)
file(GLOB FUNC_CXX_SOURCES ${CMAKE_SOURCE_DIR}/RecompiledFuncs/*.cpp)

target_sources(RecompiledFuncs PRIVATE ${FUNC_C_SOURCES} ${FUNC_CXX_SOURCES})

# PatchesLib - Library containing the recompiled output for any custom function patches
add_library(PatchesLib STATIC)

target_compile_options(PatchesLib PRIVATE
    # -Wno-unused-but-set-variable
    -fno-strict-aliasing
    -Wno-unused-variable
    -Wno-implicit-function-declaration
)

target_include_directories(PatchesLib PRIVATE
    ${CMAKE_SOURCE_DIR}/include
    ${CMAKE_SOURCE_DIR}/lib/N64ModernRuntime/ultramodern/include
    ${CMAKE_SOURCE_DIR}/lib/N64ModernRuntime/librecomp/include
    ${CMAKE_SOURCE_DIR}/lib/N64ModernRuntime/N64Recomp/include
)

target_sources(PatchesLib PRIVATE
    ${CMAKE_SOURCE_DIR}/RecompiledPatches/patches.c
    ${CMAKE_SOURCE_DIR}/RecompiledPatches/patches_bin.c
)

set_source_files_properties(${CMAKE_SOURCE_DIR}/RecompiledPatches/patches.c PROPERTIES COMPILE_FLAGS -fno-strict-aliasing)

# Build/regenerate patch sources for desktop/native builds. Android Gradle
# builds treat RecompiledPatches as prepared source inputs because CMake/Ninja
# clean deletes files declared as generated OUTPUTs, which makes
# :app:clean followed by :app:assembleDebug non-reproducible.
if (NOT CMAKE_SYSTEM_NAME MATCHES "Android")
    if(NOT DEFINED PATCHES_C_COMPILER)
        set(PATCHES_C_COMPILER clang)
    endif()

    if(NOT DEFINED PATCHES_LD)
        set(PATCHES_LD ld.lld)
    endif()

    add_custom_target(PatchesBin
        COMMAND ${CMAKE_COMMAND} -E env CC=${PATCHES_C_COMPILER} LD=${PATCHES_LD} make
        WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}/patches
        BYPRODUCTS ${CMAKE_SOURCE_DIR}/patches/patches.elf
    )

    # Generate patches_bin.c from patches.bin
    add_custom_command(OUTPUT ${CMAKE_SOURCE_DIR}/RecompiledPatches/patches_bin.c
        COMMAND file_to_c ${CMAKE_SOURCE_DIR}/patches/patches.bin bk_patches_bin ${CMAKE_SOURCE_DIR}/RecompiledPatches/patches_bin.c ${CMAKE_SOURCE_DIR}/RecompiledPatches/patches_bin.h
        DEPENDS ${CMAKE_SOURCE_DIR}/patches/patches.bin
    )

    # Recompile patches elf into patches.c and patches.bin
    add_custom_command(OUTPUT
                           ${CMAKE_SOURCE_DIR}/patches/patches.bin
                           ${CMAKE_SOURCE_DIR}/RecompiledPatches/patches.c
                           ${CMAKE_SOURCE_DIR}/RecompiledPatches/recomp_overlays.inl
                           ${CMAKE_SOURCE_DIR}/RecompiledPatches/funcs.h
                       # TODO: Look into why modifying patches requires two builds to take
                       COMMAND ./N64Recomp patches.toml
                       WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
                       DEPENDS ${CMAKE_SOURCE_DIR}/patches/patches.elf
    )
endif()

# Main executable / Android SDLActivity shared library.
if (CMAKE_SYSTEM_NAME MATCHES "Android" AND BANJO_ANDROID_RUNTIME_APK)
    add_library(main SHARED)
    set(BANJO_RECOMP_TARGET main)
    target_compile_definitions(main PRIVATE BANJO_ANDROID_RUNTIME_APK=1)
    if (BANJO_ANDROID_DEV_FULL_APK)
        target_compile_definitions(main PRIVATE BANJO_ANDROID_DEV_FULL_APK=1)
    endif()
else()
    add_executable(BanjoRecompiled)
    set(BANJO_RECOMP_TARGET BanjoRecompiled)
endif()

set (SOURCES
    ${CMAKE_SOURCE_DIR}/src/main/launcher_animation.cpp
    ${CMAKE_SOURCE_DIR}/src/main/main.cpp
    ${CMAKE_SOURCE_DIR}/src/main/register_overlays.cpp
    ${CMAKE_SOURCE_DIR}/src/main/register_patches.cpp
    ${CMAKE_SOURCE_DIR}/src/main/theme.cpp

    ${CMAKE_SOURCE_DIR}/src/game/config.cpp
    ${CMAKE_SOURCE_DIR}/src/game/debug.cpp
    ${CMAKE_SOURCE_DIR}/src/game/recomp_api.cpp
    ${CMAKE_SOURCE_DIR}/src/game/recomp_extension_api.cpp
    ${CMAKE_SOURCE_DIR}/src/game/recomp_data_api.cpp
    ${CMAKE_SOURCE_DIR}/src/game/rom_decompression.cpp

    ${CMAKE_SOURCE_DIR}/rsp/n_aspMain.cpp
)

target_include_directories(${BANJO_RECOMP_TARGET} PRIVATE
    ${CMAKE_SOURCE_DIR}/include
    ${CMAKE_SOURCE_DIR}/lib/N64ModernRuntime/N64Recomp/include
    ${CMAKE_SOURCE_DIR}/lib/N64ModernRuntime/thirdparty/sse2neon
    ${CMAKE_SOURCE_DIR}/lib/rt64/src/contrib
    ${CMAKE_SOURCE_DIR}/lib/rt64/src/contrib/hlslpp/include
    ${CMAKE_SOURCE_DIR}/lib/rt64/src/contrib/dxc/inc
    ${CMAKE_SOURCE_DIR}/lib/rt64/src
    ${CMAKE_SOURCE_DIR}/lib/rt64/src/rhi
    ${CMAKE_SOURCE_DIR}/lib/rt64/src/render
    ${CMAKE_SOURCE_DIR}/lib/RecompFrontend/recompinput/include
    ${CMAKE_SOURCE_DIR}/lib/RecompFrontend/recompui/include
    ${CMAKE_SOURCE_DIR}/lib/RecompFrontend/recompui/src
    ${CMAKE_SOURCE_DIR}/lib/rt64/src/contrib/nativefiledialog-extended/src/include
    ${CMAKE_SOURCE_DIR}/lib/SlotMap
    ${CMAKE_CURRENT_BINARY_DIR}
)

# Generate icon_bytes.c from the app icon PNG.
add_custom_command(OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/icon_bytes.c ${CMAKE_CURRENT_BINARY_DIR}/icon_bytes.h
    COMMAND file_to_c ${CMAKE_SOURCE_DIR}/icons/app.png icon_bytes ${CMAKE_CURRENT_BINARY_DIR}/icon_bytes.c ${CMAKE_CURRENT_BINARY_DIR}/icon_bytes.h
    DEPENDS ${CMAKE_SOURCE_DIR}/icons/app.png
)

target_sources(${BANJO_RECOMP_TARGET} PRIVATE ${CMAKE_CURRENT_BINARY_DIR}/icon_bytes.c)

if(CMAKE_SIZEOF_VOID_P EQUAL 8 AND CMAKE_SYSTEM_PROCESSOR MATCHES "x86_64|amd64|AMD64")
    target_compile_options(${BANJO_RECOMP_TARGET} PRIVATE
        -march=nehalem
        -fno-strict-aliasing
        -fms-extensions
    )
else()
    target_compile_options(${BANJO_RECOMP_TARGET} PRIVATE
        -fno-strict-aliasing
        -fms-extensions
    )
endif()

if (MSVC)
    # Disable identical code folding, since this breaks mod function patching as multiple functions can get merged into one.
    target_link_options(${BANJO_RECOMP_TARGET} PRIVATE /OPT:NOICF)
elseif (APPLE)
    # Use a wrapper around ld64 that respects segprot's `max_prot` value in order
    # to make our executable memory writable (required for mod function patching)
    target_link_options(${BANJO_RECOMP_TARGET} PRIVATE
        "-fuse-ld=${CMAKE_SOURCE_DIR}/.github/macos/ld64"
    )
endif()

if (WIN32)
    include(FetchContent)

    if (DEFINED ENV{SDL2_VERSION})
        set(SDL2_VERSION $ENV{SDL2_VERSION})
    else()
        set(SDL2_VERSION "2.30.3")
    endif()

    # Fetch SDL2 on windows
    FetchContent_Declare(
        sdl2
        URL https://github.com/libsdl-org/SDL/releases/download/release-${SDL2_VERSION}/SDL2-devel-${SDL2_VERSION}-VC.zip
    )
    FetchContent_MakeAvailable(sdl2)
    target_include_directories(${BANJO_RECOMP_TARGET} PRIVATE
        ${sdl2_SOURCE_DIR}/include
    )
    target_link_directories(${BANJO_RECOMP_TARGET} PRIVATE
        ${sdl2_SOURCE_DIR}/lib/x64
    )

    # Copy SDL2 and dxc DLLs to output folder as post build step
    add_custom_command(TARGET BanjoRecompiled POST_BUILD
        COMMAND ${CMAKE_COMMAND} -E copy_if_different
            "${sdl2_SOURCE_DIR}/lib/x64/SDL2.dll"
            "${CMAKE_SOURCE_DIR}/lib/rt64/src/contrib/dxc/bin/x64/dxil.dll"
            "${CMAKE_SOURCE_DIR}/lib/rt64/src/contrib/dxc/bin/x64/dxcompiler.dll"
            $<TARGET_FILE_DIR:BanjoRecompiled>)

    set_target_properties(
        ${BANJO_RECOMP_TARGET}
        PROPERTIES
            LINK_FLAGS_DEBUG "/SUBSYSTEM:CONSOLE"
            LINK_FLAGS_RELEASE "/SUBSYSTEM:WINDOWS /ENTRY:mainCRTStartup"
            LINK_FLAGS_RELWITHDEBINFO  "/SUBSYSTEM:WINDOWS /ENTRY:mainCRTStartup"
            LINK_FLAGS_MINSIZEREL "/SUBSYSTEM:WINDOWS /ENTRY:mainCRTStartup"
    )

    target_sources(${BANJO_RECOMP_TARGET} PRIVATE ${CMAKE_SOURCE_DIR}/icons/app.rc)
    target_link_libraries(${BANJO_RECOMP_TARGET} PRIVATE SDL2 Winmm.lib)
endif()

if (APPLE)
    find_package(SDL2 REQUIRED)
    target_include_directories(${BANJO_RECOMP_TARGET} PRIVATE ${SDL2_INCLUDE_DIRS})

    set(CMAKE_THREAD_PREFER_PTHREAD TRUE)
    set(THREADS_PREFER_PTHREAD_FLAG TRUE)
    find_package(Threads REQUIRED)

    target_link_libraries(${BANJO_RECOMP_TARGET} PRIVATE ${CMAKE_DL_LIBS} Threads::Threads SDL2::SDL2)

    include(${CMAKE_SOURCE_DIR}/.github/macos/apple_bundle.cmake)
endif()

if (CMAKE_SYSTEM_NAME MATCHES "Linux")
    find_package(SDL2 REQUIRED)
    find_package(X11 REQUIRED)

    add_compile_definitions("PLUME_SDL_VULKAN_ENABLED")
    add_compile_definitions("RT64_SDL_WINDOW_VULKAN")

    message(STATUS "SDL2_FOUND = ${SDL2_FOUND}")
    message(STATUS "SDL2_INCLUDE_DIRS = ${SDL2_INCLUDE_DIRS}")

    target_include_directories(${BANJO_RECOMP_TARGET} PRIVATE ${SDL2_INCLUDE_DIRS})

    message(STATUS "X11_FOUND = ${X11_FOUND}")
    message(STATUS "X11_Xrandr_FOUND = ${X11_Xrandr_FOUND}")
    message(STATUS "X11_INCLUDE_DIR = ${X11_INCLUDE_DIR}")
    message(STATUS "X11_LIBRARIES = ${X11_LIBRARIES}")

    target_include_directories(${BANJO_RECOMP_TARGET} PRIVATE ${X11_INCLUDE_DIR} ${X11_Xrandr_INCLUDE_PATH})
    target_link_libraries(${BANJO_RECOMP_TARGET} PRIVATE ${X11_LIBRARIES} ${X11_Xrandr_LIB})

    find_package(Freetype REQUIRED)

    message(STATUS "FREETYPE_FOUND = ${FREETYPE_FOUND}")
    message(STATUS "FREETYPE_INCLUDE_DIRS = ${FREETYPE_INCLUDE_DIRS}")
    message(STATUS "FREETYPE_LIBRARIES = ${FREETYPE_LIBRARIES}")

    include_directories(${FREETYPE_LIBRARIES})
    target_link_libraries(${BANJO_RECOMP_TARGET} PRIVATE ${FREETYPE_LIBRARIES} SDL2::SDL2)

    set(CMAKE_THREAD_PREFER_PTHREAD TRUE)
    set(THREADS_PREFER_PTHREAD_FLAG TRUE)
    find_package(Threads REQUIRED)

    target_link_libraries(${BANJO_RECOMP_TARGET} PRIVATE "-latomic -static-libstdc++" ${CMAKE_DL_LIBS} Threads::Threads)
endif()

if (CMAKE_SYSTEM_NAME MATCHES "Android")
    find_package(SDL2 REQUIRED)

    add_compile_definitions("PLUME_SDL_VULKAN_ENABLED")
    add_compile_definitions("RT64_SDL_WINDOW_VULKAN")

    target_include_directories(${BANJO_RECOMP_TARGET} PRIVATE ${SDL2_INCLUDE_DIRS})
    target_link_libraries(${BANJO_RECOMP_TARGET} PRIVATE SDL2::SDL2 android log vulkan)
endif()

# TODO fix the rt64 CMake script so that this doesn't need to be duplicated here
# For DXC
set (DXC_COMMON_OPTS "-I${PROJECT_SOURCE_DIR}/src")
set (DXC_DXIL_OPTS "-Wno-ignored-attributes")
set (DXC_SPV_OPTS "-spirv" "-fspv-target-env=vulkan1.0" "-fvk-use-dx-layout")
set (DXC_PS_OPTS "${DXC_COMMON_OPTS}" "-E" "PSMain" "-T ps_6_0" "-D DYNAMIC_RENDER_PARAMS")
set (DXC_VS_OPTS "${DXC_COMMON_OPTS}" "-E" "VSMain" "-T vs_6_0" "-D DYNAMIC_RENDER_PARAMS" "-fvk-invert-y")
set (DXC_CS_OPTS "${DXC_COMMON_OPTS}" "-E" "CSMain" "-T cs_6_0")
set (DXC_GS_OPTS "${DXC_COMMON_OPTS}" "-E" "GSMain" "-T gs_6_0")
set (DXC_RT_OPTS "${DXC_COMMON_OPTS}" "-D" "RT_SHADER" "-T" "lib_6_3" "-fspv-target-env=vulkan1.1spirv1.4" "-fspv-extension=SPV_KHR_ray_tracing" "-fspv-extension=SPV_EXT_descriptor_indexing")

if (${WIN32})
    set (DXC "${PROJECT_SOURCE_DIR}/lib/rt64/src/contrib/dxc/bin/x64/dxc.exe")
    add_compile_definitions(NOMINMAX)
else()
    if (APPLE)
        # Apple's binary is universal, so it'll work on both x86_64 and arm64
        set (DXC "DYLD_LIBRARY_PATH=${PROJECT_SOURCE_DIR}/lib/rt64/src/contrib/dxc/lib/arm64" "${PROJECT_SOURCE_DIR}/lib/rt64/src/contrib/dxc/bin/arm64/dxc-macos")
        if(CMAKE_SIZEOF_VOID_P EQUAL 8 AND CMAKE_SYSTEM_PROCESSOR MATCHES "x86_64|amd64|AMD64")
            set(SPIRVCROSS "DYLD_LIBRARY_PATH=${PROJECT_SOURCE_DIR}/lib/rt64/src/contrib/spirv-cross/lib/x64" "${PROJECT_SOURCE_DIR}/lib/rt64//src/contrib/spirv-cross/bin/x64/spirv-cross")
        else()
            set(SPIRVCROSS "DYLD_LIBRARY_PATH=${PROJECT_SOURCE_DIR}/lib/rt64/src/contrib/spirv-cross/lib/arm64" "${PROJECT_SOURCE_DIR}/lib/rt64//src/contrib/spirv-cross/bin/x64/spirv-cross")
        endif()
    else()
        # Android and other cross-builds run DXC on the build host, not the target.
        if(CMAKE_HOST_SYSTEM_PROCESSOR MATCHES "x86_64|amd64|AMD64")
            set (DXC "LD_LIBRARY_PATH=${PROJECT_SOURCE_DIR}/lib/rt64/src/contrib/dxc/lib/x64" "${PROJECT_SOURCE_DIR}/lib/rt64/src/contrib/dxc/bin/x64/dxc-linux")
        else()
            set (DXC "LD_LIBRARY_PATH=${PROJECT_SOURCE_DIR}/lib/rt64/src/contrib/dxc/lib/arm64" "${PROJECT_SOURCE_DIR}/lib/rt64/src/contrib/dxc/bin/arm64/dxc-linux")
        endif()
    endif()
endif()

set(RECOMP_FRONTEND_N64MODERNRUNTIME_PATH ${CMAKE_SOURCE_DIR}/lib/N64ModernRuntime)
set(RECOMP_FRONTEND_RT64_PATH ${CMAKE_SOURCE_DIR}/lib/rt64)

add_subdirectory(${CMAKE_SOURCE_DIR}/lib/RecompFrontend)

if (CMAKE_SYSTEM_NAME MATCHES "Android" AND BANJO_ANDROID_DEV_FULL_APK)
    # ui_launcher.cpp is compiled into the recompui static library, not the final
    # Android libmain target, so the native auto-ROM gate must be visible here.
    target_compile_definitions(recompui PRIVATE BANJO_ANDROID_DEV_FULL_APK=1)
endif()

target_link_libraries(${BANJO_RECOMP_TARGET} PRIVATE
    PatchesLib
    RecompiledFuncs
    recompui
    recompinput
    librecomp
    ultramodern
    rt64
    nfd
)

# Embed all .nrm files in the "mods" directory
file(GLOB NRM_FILES "${CMAKE_SOURCE_DIR}/mods/*.nrm")

set(GENERATED_NRM_SOURCES "")

foreach(NRM_FILE ${NRM_FILES})
    get_filename_component(NRM_NAME ${NRM_FILE} NAME_WE)
    set(OUT_C "${CMAKE_CURRENT_BINARY_DIR}/mods/${NRM_NAME}.c")
    set(OUT_H "${CMAKE_CURRENT_BINARY_DIR}/mods/${NRM_NAME}.h")

    add_custom_command(
        OUTPUT ${OUT_C} ${OUT_H}
        COMMAND file_to_c ${NRM_FILE} ${NRM_NAME} ${OUT_C} ${OUT_H}
        DEPENDS ${NRM_FILE}
    )

    list(APPEND GENERATED_NRM_SOURCES ${OUT_C})
endforeach()

target_sources(${BANJO_RECOMP_TARGET} PRIVATE ${GENERATED_NRM_SOURCES})

target_sources(${BANJO_RECOMP_TARGET} PRIVATE ${SOURCES})

if (CMAKE_SYSTEM_NAME MATCHES "Android" AND BANJO_ANDROID_VULKAN_SMOKE_PROBE)
    target_sources(${BANJO_RECOMP_TARGET} PRIVATE ${CMAKE_SOURCE_DIR}/src/android/vulkan_smoke_probe.cpp)
    target_compile_definitions(${BANJO_RECOMP_TARGET} PRIVATE BANJO_ANDROID_VULKAN_SMOKE_PROBE=1)
endif()

if (CMAKE_SYSTEM_NAME MATCHES "Android" AND BANJO_ANDROID_RUNTIME_APK)
    target_sources(${BANJO_RECOMP_TARGET} PRIVATE
        ${CMAKE_SOURCE_DIR}/src/android/custom_driver_manager.cpp
        ${CMAKE_SOURCE_DIR}/src/android/save_storage_manager.cpp
    )
    target_compile_definitions(${BANJO_RECOMP_TARGET} PRIVATE BANJO_ANDROID_CUSTOM_DRIVER_MANAGER=1)
    if (BANJO_ANDROID_CUSTOM_VULKAN_DRIVER)
        target_compile_definitions(${BANJO_RECOMP_TARGET} PRIVATE BANJO_ANDROID_CUSTOM_VULKAN_DRIVER=1)
        target_link_libraries(${BANJO_RECOMP_TARGET} PRIVATE adrenotools)
        add_dependencies(${BANJO_RECOMP_TARGET} main_hook file_redirect_hook gsl_alloc_hook hook_impl)
    endif()
endif()

if (BANJO_ANDROID_RENDERER_STUB)
    target_sources(${BANJO_RECOMP_TARGET} PRIVATE ${CMAKE_SOURCE_DIR}/src/android/null_renderer_context.cpp)
endif()

set_property(TARGET ${BANJO_RECOMP_TARGET} PROPERTY VS_DEBUGGER_WORKING_DIRECTORY "${CMAKE_SOURCE_DIR}")
