# Battlefield 2: Modern Combat (original Xbox), statically recompiled

cmake_minimum_required(VERSION 3.25)
project(bf2mc LANGUAGES C CXX)

set(CMAKE_CXX_STANDARD 20)
set(CMAKE_CXX_STANDARD_REQUIRED ON)

# the SDK: sdk/ here, two folders up inside the SDK's templates, a checkout beside this repository, else downloaded
if(EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/sdk/cmake/XbeRecomp.cmake)
    set(SDK ${CMAKE_CURRENT_SOURCE_DIR}/sdk)
elseif(EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/../../cmake/XbeRecomp.cmake)
    set(SDK ${CMAKE_CURRENT_SOURCE_DIR}/../..)
elseif(EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/../XboxXBE-Recomp/cmake/XbeRecomp.cmake)
    set(SDK ${CMAKE_CURRENT_SOURCE_DIR}/../XboxXBE-Recomp)
else()
    include(FetchContent)
    FetchContent_Declare(xbe_sdk GIT_REPOSITORY https://github.com/TGP482/XboxXBE-Recomp.git GIT_TAG main)
    FetchContent_MakeAvailable(xbe_sdk)
    set(SDK ${xbe_sdk_SOURCE_DIR})
endif()
include(${SDK}/cmake/XbeRecomp.cmake)

file(GLOB XBE_HOST_SOURCES CONFIGURE_DEPENDS src/*/*.cpp)
list(FILTER XBE_HOST_SOURCES EXCLUDE REGEX "/src/game/")

# partitions as xbe_symbols wrote them into config/game.toml
set_property(DIRECTORY APPEND PROPERTY CMAKE_CONFIGURE_DEPENDS config/game.toml)
if(EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/config/game.toml)
    file(STRINGS config/game.toml GAME_PARTITIONS REGEX "^partitions *=")
    string(REGEX MATCH "[0-9]+" GAME_PARTITIONS "${GAME_PARTITIONS}")
endif()
# no config yet: build.bat writes it with xbe_symbols, the change reconfigures
if(NOT GAME_PARTITIONS)
    set(GAME_PARTITIONS 8)
endif()

# target name = GAME_EXE in build.bat, xbe = GAME_XBE
add_xbe_image(BF2MC default.xbe game.toml ${GAME_PARTITIONS} game)

# NVIDIA Reflex through NVAPI (patches/sdk-zzz-reflex.patch): nvapi/ is NVIDIA's NVAPI repository, which CI clones;
# without it the build goes on and Reflex shows as not available
set(NVAPI_DIR ${CMAKE_CURRENT_SOURCE_DIR}/nvapi)
if(EXISTS ${NVAPI_DIR}/nvapi.h AND EXISTS ${NVAPI_DIR}/amd64/nvapi64.lib)
    target_include_directories(BF2MC PRIVATE ${NVAPI_DIR})
    target_compile_definitions(BF2MC PRIVATE HAS_NVAPI=1)
    target_link_libraries(BF2MC PRIVATE ${NVAPI_DIR}/amd64/nvapi64.lib)
    message(STATUS "NVAPI: Reflex built in")
else()
    message(STATUS "NVAPI: not found, Reflex left out")
endif()
